registry-switcher.cmd

 
@echo off & setlocal
Rem #####################################################
Rem # 
Rem # SCRIPT: registry-switcher.cmd
Rem # 
Rem #  add or delete a registry entry
Rem # 
Rem # usage:  registry-switcher.cmd
Rem # 
Rem # Version 0.0.1 Mark Wolfgruber  
Rem # 
Rem #####################################################
 
set _Key=SftpNetDrive
set _RegEntry=HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Run
set _Value="C:\Program Files (x86)\SFTP Net Drive\SftpNetDrive.exe" /startup
set "_Value=%_Value:"=\"%"
set "_Value=%_Value:(=^^(%"
set "_Value=%_Value:)=^^)%"
set _Type=REG_SZ
set _answer=N
set "_regadd=REG ADD "%_RegEntry%" /f /v "%_Key%" /t "%_Type%" /d "%_Value%" 
set "_regdel=REG DELETE "%_RegEntry%" /f /v "%_Key%""
set "_regquery=REG QUERY %_RegEntry% /f %_Key% /t %_Type% /c /e "
 
echo.
echo.Reg-Entry-Switcher
echo.==================
echo.
echo.Entry: %_RegEntry%
echo.Key  : %_Key%
echo.Type : %_Type%
echo.Value: %_Value%
echo.
 
%_regquery% && (
  set _query=found
) || (
  set _query=missing
)
echo.%_query% %_Key% 
 
if "%_query%"=="found" goto found
if "%_query%"=="missing" goto missing
 
echo.NEVER SEE THIS MESSAGE
pause
goto end
 
:found
 
  set /p _answer=remove %_Key% from Registry now? [Y/N] 
    if /i "%_answer%"=="J" set _answer=Y
    if /i "%_answer%"=="Z" set _answer=Y
    if /i "%_answer%"=="Y" (
    %_regdel%
     ) 
  goto end
 
:missing
  set /p _answer=add %_Key% to Registry now? [Y/N] 
    if /i "%_answer%"=="J" set _answer=Y
    if /i "%_answer%"=="Z" set _answer=Y
    if /i "%_answer%"=="Y" (
    %_regadd%
     ) 
  goto end
 
:end
  echo.
  echo.---------------------------------------------------------------------------
  echo.
 
  %_regquery% && (
    set _query=found
  ) || (
    set _query=missing
  )
  echo.%_query% %_Key% 
 
  pause